SQLの窓

2013年12月30日


VBScript : ini ファイルの値を取得する

cscript.exe ini.vbs "PATH" セクション名 エントリ名
で、値を echo します。バッチファイルを使うならば、同じディレクトリに ini.bat を作成して、
@echo off
cscript.exe //NOLOGO "%~dp0ini.vbs" "%1" %2 %3
とすると、パスの通ったディレクトリに両方置いて、"ini" というコマンドの出来上がりです エラーメッセージは、イベントビュアーの『アプリケーション』に記録されます
' ログ出力用
Set WshShell = WScript.CreateObject("WScript.Shell")

' 使用方法の表示
if Wscript.Arguments.Count = 0 then
	Wscript.Echo "Usage : cscript.exe ini.vbs ""PATH"" section entry"
	Wscript.Echo "例	 : cscript.exe ini.vbs ""c:\php\php.ini"" php error_reporting"
	Wscript.Quit
end if
' ファイルシステムアクセス用
Set Fs = CreateObject( "Scripting.FileSystemObject" )
' 引数の数をチェック( パス セクション エントリ )
if Wscript.Arguments.Count <> 3 then
	' 引数の数が誤っている場合は終了
	WshShell.LogEvent 1, "引数の数が誤っています"
	Wscript.Quit
end if
' ファイルを開く
on error resume next
Set InObj = Fs.OpenTextFile( Wscript.Arguments(0), 1 )
if Err.Number <> 0 then
	' ファイルアクセスエラーの場合は終了
	WshShell.LogEvent 1, Err.Description & ":" & Wscript.Arguments(0)
	Wscript.Quit
end if
on error goto 0

' 検索処理用のフラグ
search = false
' 読込みループ
Do While not InObj.AtEndOfStream
	' 行単位の読込み
	Buffer = InObj.ReadLine
	' 空の行は無視する
	if Trim(Buffer) <> "" then
		' 対象セクションを発見した場合
		if Ucase(Trim(Buffer)) = "[" & Ucase(Wscript.Arguments(1)) & "]" then
			search = true
		else
			' 一度発見した場合は同じセクションは無いのでこちらへ
			' 発見してない場合もこちらに来ますが、search が true なら発見済み
			if search then
				' 次のセクションを発見した場合は、該当するエントリが無い事を示す
				if Left(Trim(Buffer),1) = "[" then
					' 処理を終了する為、ループを終了する
					WshShell.LogEvent 1, "指定されたエントリを発見できませんでした:" & Wscript.Arguments(2)
					Exit Do
				end if
				' 先頭行がセミコロンの場合は、コメントとみなします
				RealLine = Split(Buffer,";")
				' セミコロンがあった場合、RealLine(0) は空です
				Entry = Split(RealLine(0),"=")
				' 通常行の場合、= が見つかればエントリです
				if ( Ubound(Entry) = 1 ) then
					' エントリが検索対象かどうかをチェック
					if Ucase(Trim(Entry(0))) = Ucase(Wscript.Arguments(2)) then
						' 一致した場合のみ値を表示
						Wscript.Echo(Trim(Entry(1)))
						' ファイルを閉じて終了する
						InObj.Close
						Wscript.Quit
					End if
				end if
			end if
		end if
	end if
Loop
' ここは、検索対象が発見できなかった場合の終了です
InObj.Close
if search then
	WshShell.LogEvent 1, "指定されたエントリを発見できませんでした:" & Wscript.Arguments(2)
else
	WshShell.LogEvent 1, "指定されたセクションを発見できませんでした:" & Wscript.Arguments(1)
end if
Wscript.Echo



タグ:VBScript
posted by lightbox at 2013-12-30 05:16 | VBS + オブジェクト | このブログの読者になる | 更新情報をチェックする

2013年12月29日


ブログにストリートビューを簡単に埋め込む

緯度と経度が必要です。角度や向きや位置移動は、実際にストリトービューを操作して取得します。決定したら『設定変更ボタン』で貼り付けコードを取得します。この際、ストリートビューを画像化する URL も取得できます。



ブログ等で使えるストリートビューコードを取得します


タグ:google
posted by lightbox at 2013-12-29 19:57 | WEBサービス | このブログの読者になる | 更新情報をチェックする

2013年12月28日


かな/ローマ字入力を切り替える

簡単変更は、CTRL+SHIFT+カタカナ・ひらがな

正式には、ALT+カタカナ・ひらがな

OSバージョンやIMEバージョンに依存するかもですが、正式文書はこちらです。

Windows 8 での情報

「ローマ字入力」 と 「かな入力」 の切り替え方法( プロパティ設定 )

※ ▲には、『Windows 8 のタッチ キーボードで「かな入力」をする場合の手順が掲載されています。



posted by lightbox at 2013-12-28 09:40 | Windows | このブログの読者になる | 更新情報をチェックする
Seesaa の各ページの表示について
Seesaa の 記事がたまに全く表示されない場合があります。その場合は、設定> 詳細設定> ブログ設定 で 最新の情報に更新の『実行ボタン』で記事やアーカイブが最新にビルドされます。

Seesaa のページで、アーカイブとタグページは要注意です。タグページはコンテンツが全く無い状態になりますし、アーカイブページも歯抜けページはコンテンツが存在しないのにページが表示されてしまいます。

また、カテゴリページもそういう意味では完全ではありません。『カテゴリID-番号』というフォーマットで表示されるページですが、実際存在するより大きな番号でも表示されてしまいます。

※ インデックスページのみ、実際の記事数を超えたページを指定しても最後のページが表示されるようです

対処としては、このようなヘルプ的な情報を固定でページの最後に表示するようにするといいでしょう。具体的には、メインの記事コンテンツの下に『自由形式』を追加し、アーカイブとカテゴリページでのみ表示するように設定し、コンテンツを用意するといいと思います。


※ エキスパートモードで表示しています

アーカイブとカテゴリページはこのように簡単に設定できますが、タグページは HTML 設定を直接変更して、以下の『タグページでのみ表示される内容』の記述方法で設定する必要があります

<% if:page_name eq 'archive' -%>
アーカイブページでのみ表示される内容
<% /if %>

<% if:page_name eq 'category' -%>
カテゴリページでのみ表示される内容
<% /if %>

<% if:page_name eq 'tag' -%>
タグページでのみ表示される内容
<% /if %>
この記述は、以下の場所で使用します
container 終わり

フリーフォントで簡単ロゴ作成
フリーフォントでボタン素材作成
フリーフォントで吹き出し画像作成
フリーフォントではんこ画像作成
ほぼ自由に利用できるフリーフォント
フリーフォントの書体見本とサンプル
画像を大きく見る為のウインドウを開くボタンの作成

CSS ドロップシャドウの参考デモ
BUTTONS (CSS でボタン)
イラストAC
ぱくたそ
写真素材 足成
フリーフォント一覧
utf8 文字ツール
右サイド 終わり
base 終わり