SQLの窓

2015年04月24日


Small Basic。拡張ライブラリを追加して、非同期アニメーションで弾が当たったら爆発効果



TechNet Small Basic LitDev Extension Version 1.1.0.2 を追加インストール( 実際はファイルをコピーするだけ )と、色々びっくりするようなな機能が簡単に実行できるようになります。

Small Basic をめちゃくちゃ拡張するライブラリ

その中でも、とてもタイムリーだったのが、非同期アニメーションを分割画像を読み込むだけで簡単に実装できるところです。
GraphicsWindow.BackgroundColor = "DarkGray"
LDGraphicsWindow.PauseUpdates() ' 画像をロードしている間表示しない
LDShapes.AnimationInterval = 0 ' アニメーションしない
anim = LDShapes.AddAnimatedImage(Program.Directory+"\anim.png","True",4,4)
Shapes.Move(anim,100,100)	' 表示位置
LDShapes.AnimationInterval = 75 ' 75 ms インターバルでアニメーション
LDGraphicsWindow.ResumeUpdates() ' 画面表示
上のコードは、サンプルコードそのままです。このコードでは、AddAnimatedImage の第二引数が、"True" なので自動的に繰り返し表示を行います。しかし、目的はボール(弾) が当たった時に一回だけアニメーションするので以下のように実装する事になります。
' ウィンドウの背景色
GraphicsWindow.BackgroundColor = "White"
' ウインドウの位置
GraphicsWindow.Left = 100
GraphicsWindow.Top = 40
' リサイズできないようにする
GraphicsWindow.CanResize = 0

LDShapes.AnimationInterval = 25 ' 爆発アニメーション用
' アニメーション画像の読み込み( 第二引数で自動繰り返しをしない )
explosion = LDShapes.AddAnimatedImage(Program.Directory+"\anim.png","False",4,4)
LDShapes.ZIndex( explosion, 1000 )  ' 爆発なので手前に表示する
Shapes.Zoom(explosion,2,2)          ' 爆発の表示サイズを倍にする
' 爆発画像を非表示にする
Shapes.HideShape(explosion)

LoadImage_Url = "https://lh5.googleusercontent.com/-3IWAlBbUSYs/VLgFjekftnI/AAAAAAAAYKw/VM5FI7bYNzw/s800/142133580685821985693.jpeg"
'LoadImage_Url = ""
LoadImage_Opacity = 50
LoadImage()

' ******************************************
' 白いボール
' ******************************************
GraphicsWindow.BrushColor = "#ffffff"   ' ボールの塗りつぶし色
Ball_Speed = 1
Ball_Size = 30  ' ボールの直径
Ball_Name = Shapes.AddEllipse(Ball_Size, Ball_Size)
' 初期位置
Ball_x = LoadImage_width / 2 - Ball_Size / 2  ' ボールの中心を画面の中心に
Ball_y = Ball_Size * -1   ' ボールが隠れる位置( 直径ぶん、上辺の上 )
Shapes.Move( Ball_Name, Ball_x, Ball_y )
Sub Ball

  Ball_y = Ball_y - Ball_Speed
  If Ball_y > (Ball_Size * -2) Then
    Shapes.Move( Ball_Name, Ball_x, Ball_y )
    ' TextWindow.WriteLine(Ball_y) 
  Else
    Ball_y = Ball_Size * -1
  EndIf

EndSub

' ******************************************
' 四角形
' ******************************************
GraphicsWindow.BrushColor = "#00ff00"   ' 四角形の塗りつぶし色
Rect_Speed = 0.3
Rect_Size = 40  ' 高さ
Rect_Name = Shapes.AddRectangle(Rect_Size * 2, Rect_Size)   ' 幅は、高さの倍
' 初期位置
Rect_x = Rect_Size * -2   ' 箱が隠れる位置( 幅ぶん左 )  
Rect_y = Rect_Size * 1    ' 箱一個ぶん下
Shapes.Move( Rect_Name, Rect_x, Rect_y )
' 当たりアニメーション中フラグ
Rect_Hit_Flg = 0  '  0 は、通常時でアニメーション中では無い
Sub Rect
  If Rect_Hit_Flg = 0 then
    Rect_x = Rect_x + Rect_Speed
    If Rect_x < LoadImage_width Then
      Shapes.Move( Rect_Name, Rect_x, Rect_y )
      ' TextWindow.WriteLine(Rect_y) 
    Else
      Rect_x = Rect_Size * -2
    EndIf
    ' 当たり判定用の値を用意する
    Hit_x = Rect_x
    Hit_width = Rect_Size * 2
    Hit_y = Rect_y
    Hit_height = Rect_Size
    ' 当たり判定のチェック
    Hit()
    ' 当たり判定からの結果をこちらの条件にセットする
    Rect_Hit_Flg = Hit_Flg
    ' 当たっていたら、ボールは先に初期化しておく
    If Rect_Hit_Flg <> 0 Then
      ' ボールは消えるが、爆発アニメーションを実行
      Shapes.ShowShape(explosion)
      LDShapes.Centre(explosion,Ball_x,Ball_y)
      LDShapes.AnimationSet(explosion,1)
      
      Ball_y = Ball_Size * -1
    EndIf
  Else

    Shapes.Rotate(Rect_Name, 1000 - Rect_Hit_Flg)

    Rect_Hit_Flg = Rect_Hit_Flg - 1
    ' アニメーションが終了すると初期位置に移動
    If Rect_Hit_Flg = 0 Then
      Shapes.Rotate(Rect_Name, 0)
      Rect_x = Rect_Size * -2
    EndIf
  EndIf
  
EndSub

' ******************************************
' 当たり判定
' ******************************************
Sub Hit
  Hit_Flg = 0
  ' 当たり判定は、四角形の居る位置( 高さ ) に、ボールが到達した時で
  If Hit_y <= Ball_y And Ball_y <= Hit_y + Hit_height Then
    If Hit_x <= Ball_x + Ball_Size And Ball_x <= Hit_x + Hit_width Then
      ' アニメーション回数
      Hit_Flg = 1000
    EndIf
  EndIf
EndSub

' ******************************************
' キーイベント
' ******************************************
GraphicsWindow.KeyDown = OnKeyDown
Sub OnKeyDown

  If Ball_y <= (Ball_Size * -1) Then
    Ball_y = LoadImage_height
  EndIf
  
EndSub

' ******************************************
' アニメーションループ
' ******************************************
Loop:
  Program.Delay(1)
  Ball()
  Rect()
  
Goto Loop


' ******************************************
' グラフィックウインドウに画像を表示する
' LoadImage_Url : URL
' LoadImage_Opacity : 不透明度
' ******************************************
Sub LoadImage

  If LoadImage_Url <> "" then
    LoadImage_pic = ImageList.LoadImage(LoadImage_Url)
    LoadImage_img = Shapes.AddImage(LoadImage_pic)
    Shapes.SetOpacity(LoadImage_img, LoadImage_Opacity)
    LoadImage_width = ImageList.GetWidthOfImage(LoadImage_pic)
    LoadImage_height = ImageList.GetHeightOfImage(LoadImage_pic)
  Else
    LoadImage_width = Desktop.Width * 0.8
    LoadImage_height = Desktop.Height * 0.8
  EndIf
  GraphicsWindow.Width = LoadImage_width
  GraphicsWindow.Height = LoadImage_height
  GraphicsWindow.DrawResizedImage(LoadImage_img, 0, 0, LoadImage_width, LoadImage_height)

EndSub

LDShapes.AnimationSet(explosion,1) で、非同期でアニメーションが開始されます(1番の画像から最後の画像まで)。プログラムのループ処理は継続されるので、アニメーション中も弾を撃つ事が可能になっています。

爆発アニメーション用の背景透過 PNG



この画像はサンプルにあったものをそのまま使っています。ただ、一番右下の画像が元々の画像では小さい点が表示されていました。それでは、アニメーションの最後のフレームとして表示し続けてしまうので、何も無い透過した状態に変更しました。



posted by lightbox at 2015-04-24 15:31 | Small Basic | このブログの読者になる | 更新情報をチェックする

2015年04月23日


Small Basic。横に動く長方形をキーを押したらボールを発射して命中させて回転させるゲーム雛形



▼ 一つ前のコード
Small Basic。やはり基本はゲーム作って楽しむべきなので、キーを押したらボールを発射する雛形

Small Basic では、発行ボタンですぐ WEB上に公開して、SilverLight によって動作させる事ができます。ローカルでは画像が使えますが、WEB 上ではメモリだけで動作させるコードにする必要があります。

▼ SilverLight で実行
http://smallbasic.com/program/?BZN043

▼ 動画のソースコード
' ウィンドウの背景色
GraphicsWindow.BackgroundColor = "White"
' ウインドウの位置
GraphicsWindow.Left = 100
GraphicsWindow.Top = 40
' リサイズできないようにする
GraphicsWindow.CanResize = 0

LoadImage_Url = "https://lh5.googleusercontent.com/-3IWAlBbUSYs/VLgFjekftnI/AAAAAAAAYKw/VM5FI7bYNzw/s800/142133580685821985693.jpeg"
'LoadImage_Url = ""
LoadImage_Opacity = 50
LoadImage()

' ******************************************
' 白いボール
' ******************************************
GraphicsWindow.BrushColor = "#ffffff"   ' ボールの塗りつぶし色
Ball_Speed = 1
Ball_Size = 30  ' ボールの直径
Ball_Name = Shapes.AddEllipse(Ball_Size, Ball_Size)
' 初期位置
Ball_x = LoadImage_width / 2 - Ball_Size / 2  ' ボールの中心を画面の中心に
Ball_y = Ball_Size * -1   ' ボールが隠れる位置( 直径ぶん、上辺の上 )
Shapes.Move( Ball_Name, Ball_x, Ball_y )
Sub Ball

  Ball_y = Ball_y - Ball_Speed
  If Ball_y > (Ball_Size * -2) Then
    Shapes.Move( Ball_Name, Ball_x, Ball_y )
    ' TextWindow.WriteLine(Ball_y) 
  Else
    Ball_y = Ball_Size * -1
  EndIf

EndSub

' ******************************************
' 四角形
' ******************************************
GraphicsWindow.BrushColor = "#00ff00"   ' 四角形の塗りつぶし色
Rect_Speed = 0.5
Rect_Size = 40  ' 高さ
Rect_Name = Shapes.AddRectangle(Rect_Size * 2, Rect_Size)   ' 幅は、高さの倍
' 初期位置
Rect_x = Rect_Size * -2   ' 箱が隠れる位置( 幅ぶん左 )  
Rect_y = Rect_Size * 1    ' 箱一個ぶん下
Shapes.Move( Rect_Name, Rect_x, Rect_y )
' 当たりアニメーション中フラグ
Rect_Hit_Flg = 0  '  0 は、通常時でアニメーション中では無い
Sub Rect
  If Rect_Hit_Flg = 0 then
    Rect_x = Rect_x + Rect_Speed
    If Rect_x < LoadImage_width Then
      Shapes.Move( Rect_Name, Rect_x, Rect_y )
      ' TextWindow.WriteLine(Rect_y) 
    Else
      Rect_x = Rect_Size * -2
    EndIf
    ' 当たり判定用の値を用意する
    Hit_x = Rect_x
    Hit_width = Rect_Size * 2
    Hit_y = Rect_y
    Hit_height = Rect_Size
    ' 当たり判定のチェック
    Hit()
    ' 当たり判定からの結果をこちらの条件にセットする
    Rect_Hit_Flg = Hit_Flg
    ' 当たっていたら、ボールは先に初期化しておく
    If Rect_Hit_Flg <> 0 Then
      Ball_y = Ball_Size * -1
    EndIf
  Else

    Shapes.Rotate(Rect_Name, 1000 - Rect_Hit_Flg)

    Rect_Hit_Flg = Rect_Hit_Flg - 1
    ' アニメーションが終了すると初期位置に移動
    If Rect_Hit_Flg = 0 Then
      Shapes.Rotate(Rect_Name, 0)
      Rect_x = Rect_Size * -2
    EndIf
  EndIf
  
EndSub

' ******************************************
' 当たり判定
' ******************************************
Sub Hit
  Hit_Flg = 0
  ' 当たり判定は、四角形の居る位置( 高さ ) に、ボールが到達した時で
  If Hit_y <= Ball_y And Ball_y <= Hit_y + Hit_height Then
    If Hit_x <= Ball_x + Ball_Size And Ball_x <= Hit_x + Hit_width Then
      ' アニメーション回数
      Hit_Flg = 1000
    EndIf
  EndIf
EndSub

' ******************************************
' キーイベント
' ******************************************
GraphicsWindow.KeyDown = OnKeyDown
Sub OnKeyDown

  If Ball_y <= (Ball_Size * -1) Then
    Ball_y = LoadImage_height
  EndIf
  
EndSub

' ******************************************
' アニメーションループ
' ******************************************
Loop:
  Program.Delay(1)
  Ball()
  Rect()
  
Goto Loop


' ******************************************
' グラフィックウインドウに画像を表示する
' LoadImage_Url : URL
' LoadImage_Opacity : 不透明度
' ******************************************
Sub LoadImage

  If LoadImage_Url <> "" then
    LoadImage_pic = ImageList.LoadImage(LoadImage_Url)
    LoadImage_img = Shapes.AddImage(LoadImage_pic)
    Shapes.SetOpacity(LoadImage_img, LoadImage_Opacity)
    LoadImage_width = ImageList.GetWidthOfImage(LoadImage_pic)
    LoadImage_height = ImageList.GetHeightOfImage(LoadImage_pic)
  Else
    LoadImage_width = Desktop.Width * 0.8
    LoadImage_height = Desktop.Height * 0.8
  EndIf
  GraphicsWindow.Width = LoadImage_width
  GraphicsWindow.Height = LoadImage_height
  GraphicsWindow.DrawResizedImage(LoadImage_img, 0, 0, LoadImage_width, LoadImage_height)

EndSub


処理の要点

当然ですが、ボール(弾)を増やしたり長方形(敵)を増やしたりする事を想定してサブルーチンを作成しています。その為、Hit サブルーチンは共用する為に専用の判定用座標変数にセットされた値でチェックするようにしています。四角形のアニメーションは、四角形の描画処理と同時持ちして、ボールが当たればボールを自由にして回転アニメーションを開始します。当たった直後、ボールはすぐ使えるようになります。

現実問題として、ボールの処理は単純なので配列で行ったほうがいいでしょう。長方形の処理はいろいろな敵の動作が必要になって来るのでサブルーチン毎の処理が必要になると思います。



タグ:Small Basic
posted by lightbox at 2015-04-23 21:14 | Small Basic | このブログの読者になる | 更新情報をチェックする

2015年04月20日


Small Basic。やはり基本はゲーム作って楽しむべきなので、キーを押したらボールを発射する雛形



Microsoft Small Basic 1.1 の使い方

Microsoft からダウンロードしてインストールすると、誰でもすぐ使えるプログラミング環境です。上記リンク先内で基本部分のチュートリアルはまとめましたが、いざゲームを作るとなるといくつか注意事項があります。

画面の大きさ

これは、画像を使ってサイズ決定するようにしました。そして、画像に非透過度を設定して薄くしています。好みでいろいろな背景を設定すると同時に、サイズを指定する事になります。

ループ処理

結果的には、Goto 文で単純ループを作成しています。Program.Delay(1) は、ループ処理を安定させる為のおまじないだと思って下さい。永久ループではありますが、CPU 負荷は殆ど無く、イベント割り込みも何も問題なく動作しています。

最初、タイマーも試したのですが表示にちらつきが出た上にいろいろ弊害があるようでした。ゲーム作る場合に使う事を想定して実装されているタイマーでは無いようでした。

オブジェクト らしく

ボールを移動させるのに、サブルーチンが必要ですが、Small Basic ではそれしか無いので、サブルーチン定義の上部に初期処理を記述しています。その部分がコンストラクタみたいなものだと思って下さい。
'  ウィンドウの背景色
GraphicsWindow.BackgroundColor = "White"
'  ウインドウの位置
GraphicsWindow.Left = 100
GraphicsWindow.Top = 40
'  リサイズできないようにする
GraphicsWindow.CanResize = 0

LoadImage_Url = "https://lh5.googleusercontent.com/-3IWAlBbUSYs/VLgFjekftnI/AAAAAAAAYKw/VM5FI7bYNzw/s800/142133580685821985693.jpeg"
LoadImage_Opacity = 50
LoadImage()

' ******************************************
' 白いボール
' ******************************************
GraphicsWindow.BrushColor = "#123456"   ' ボールの塗りつぶし色
Ball_Speed = 1
Ball_Size = 30
Ball_Name = Shapes.AddEllipse(Ball_Size, Ball_Size)
Ball_x = LoadImage_width / 2
Ball_y = Ball_Size * -1
Shapes.Move( Ball_Name, Ball_x, Ball_y )
Sub Ball

  Ball_y = Ball_y - Ball_Speed
  If Ball_y > (Ball_Size * -2) Then
    Shapes.Move( Ball_Name, Ball_x, Ball_y )
    ' TextWindow.WriteLine(Ball_y)    
  Else
    Ball_y = Ball_Size * -1
  EndIf
  
EndSub

' ******************************************
' キーイベント
' ******************************************
GraphicsWindow.KeyDown = OnKeyDown
Sub OnKeyDown
  
  If Ball_y <= (Ball_Size * -1) Then
    Ball_y = LoadImage_height
  EndIf
  
EndSub

' ******************************************
' アニメーションループ
' ******************************************
Loop:  
  Program.Delay(1)
  Ball()
Goto Loop


' ******************************************
' グラフィックウインドウに画像を表示する
' LoadImage_Url : URL
' LoadImage_Opacity : 不透明度
' ******************************************
Sub LoadImage
 
  LoadImage_pic = ImageList.LoadImage(LoadImage_Url)
  LoadImage_img = Shapes.AddImage(LoadImage_pic)
  Shapes.SetOpacity(LoadImage_img, LoadImage_Opacity)
  LoadImage_width = ImageList.GetWidthOfImage(LoadImage_pic)
  LoadImage_height = ImageList.GetHeightOfImage(LoadImage_pic)
  GraphicsWindow.Width = LoadImage_width
  GraphicsWindow.Height = LoadImage_height
  GraphicsWindow.DrawResizedImage(LoadImage_img, 0, 0, LoadImage_width, LoadImage_height)

EndSub

移動処理の概要

初期処理で画面の外にボールを移動しています。その状態で何かキーを押した時のみボールを画面の一番下の中央に移動させます。後は、画面の外に出るまで移動させますが、画面の外に出た場合は変数としては初期値につねに設定されて事実上ボールには何も起こりません。

ボールの移動中は、キーが押されてもキーが押してボールを発射できるのは画面の外に出ている場合だけなので、画面内にボールが表示されている時にキーを押しても反応しません。

結果的に一つのボールに対して、Ball というサブルーチンが一つ対応しており、Ball_ と言う変数で全てまかなっているオブジェクトのようなものだと思って下さい。

この後、ボールを増やしたり他のオブジェクトを増やしていってレスポンスがどうなるかは解りませんが、簡単なゲームならすぐ作れると思います。



タグ:Small Basic
posted by lightbox at 2015-04-20 18:37 | Small Basic | このブログの読者になる | 更新情報をチェックする
Seesaa の各ページの表示について
Seesaa の 記事がたまに全く表示されない場合があります。その場合は、設定> 詳細設定> ブログ設定 で 最新の情報に更新の『実行ボタン』で記事やアーカイブが最新にビルドされます。

Seesaa のページで、アーカイブとタグページは要注意です。タグページはコンテンツが全く無い状態になりますし、アーカイブページも歯抜けページはコンテンツが存在しないのにページが表示されてしまいます。

また、カテゴリページもそういう意味では完全ではありません。『カテゴリID-番号』というフォーマットで表示されるページですが、実際存在するより大きな番号でも表示されてしまいます。

※ インデックスページのみ、実際の記事数を超えたページを指定しても最後のページが表示されるようです

対処としては、このようなヘルプ的な情報を固定でページの最後に表示するようにするといいでしょう。具体的には、メインの記事コンテンツの下に『自由形式』を追加し、アーカイブとカテゴリページでのみ表示するように設定し、コンテンツを用意するといいと思います。


※ エキスパートモードで表示しています

アーカイブとカテゴリページはこのように簡単に設定できますが、タグページは HTML 設定を直接変更して、以下の『タグページでのみ表示される内容』の記述方法で設定する必要があります

<% if:page_name eq 'archive' -%>
アーカイブページでのみ表示される内容
<% /if %>

<% if:page_name eq 'category' -%>
カテゴリページでのみ表示される内容
<% /if %>

<% if:page_name eq 'tag' -%>
タグページでのみ表示される内容
<% /if %>
この記述は、以下の場所で使用します


Windows
container 終わり

フリーフォントで簡単ロゴ作成
フリーフォントでボタン素材作成
フリーフォントで吹き出し画像作成
フリーフォントではんこ画像作成
ほぼ自由に利用できるフリーフォント
フリーフォントの書体見本とサンプル
画像を大きく見る為のウインドウを開くボタンの作成

Android SDK ポケットリファレンス
改訂版 Webデザイナーのための jQuery入門
今すぐ使えるかんたん ホームページ HTML&CSS入門
CSS ドロップシャドウの参考デモ
Google Hosted Libraries
cdnjs
BUTTONS (CSS でボタン)
イラストAC
ぱくたそ
写真素材 足成
フリーフォント一覧
utf8 文字ツール
右サイド 終わり
base 終わり