VB.net : COMの Msxml2.ServerXMLHTTP を使用して URL短縮サービス[p.tl] を使用する( JSON )

( Json.NET 4.0 Release 2 のドキュメントと readme とバイナリを同梱 )
オンラインドキュメント

パッケージにはすぐ実行できる server_xmlhttp.exe が入っていますが、
同じディレクトリに Newtonsoft.Json.Net35.dll と MSXML2.dll が必要です

★ Newtonsoft.Json.Net35.dll ( Json.NET用 : 同梱しています )
★ MSXML2.dll( Msxml2.ServerXMLHTTP参照用 : 同梱しています )
★ server_xmlhttp.exe APIキー URL で実行


以下のページは、p.tl の API の内容を記述したページです
WebAPI │ URL短縮サービス[p.tl]

メールアドレスより、API キーを取得できます
※ ここの API で戻されるのは、JSON フォーマットのみです

関係する記事

Json.NET を使用して JSON 文字列を VB.net で使用する( 逆シリアライズ )

※ JSON の処理は外部ライブラリ(Json.NET)を使っています

Imports System.Web
Imports myCom
Imports Newtonsoft.Json 
Imports Newtonsoft.Json.Linq

Module Module1

	Sub Main()

		' http 通信用のオブジェクトを作成
		Dim ServerXML As New myCom.ServerXMLHTTP60()

		' タイムアウトの設定
		Dim lResolve As Integer = 60 * 1000
		Dim lConnect As Integer = 60 * 1000
		Dim lSend As Integer = 60 * 1000
		Dim lReceive As Integer = 60 * 1000
		ServerXML.setTimeouts(lResolve, lConnect, lSend, lReceive)

		' 呼び出す URL を設定
		Dim URL As String = "http://p.tl/api/api_simple.php"

		' 変換元の文字列を引数から取得する
		' 空白を指定したい場合は、"文字列 文字列" のように指定する
		Dim arguments As String() = Environment.GetCommandLineArgs()
		' 引数は二つ許可
		if arguments.Length <> 3 then
			Console.WriteLine("引数を指定して下さい")
			Return
		end if

		' 第一引数は APIキー
		URL += "?key=" + arguments(1)

		' 第二引数は URL
		Dim TargetURL As String = arguments(2)

		' 送る為に文字列を URL エンコードする
		' System.Web.HttpUtility.UrlEncode
		TargetURL = HttpUtility.UrlEncode(TargetURL)

		URL += "&url=" + TargetURL

		' GET する為に開く
		ServerXML.open("GET", URL, False)

		' 送信
		ServerXML.send()

		Console.WriteLine(ServerXML.responseText)

		' 逆シリアライズ
		' http://json.codeplex.com/ よりダウンロードした Newtonsoft.Json.Net35.dll を使う
		Dim JsonObject As Object = JsonConvert.DeserializeObject( ServerXML.responseText )

		' 対象が解っている場合の読み取り
		Console.WriteLine( JsonObject("short_url") )

		' プロパティで一覧参照
		' Imports Newtonsoft.Json.Linq
		Dim jp As JProperty

		For Each jp In JsonObject
			' jp.Value は JToken
			Console.WriteLine( jp.Name + " : " + jp.Value.ToString() )
		Next

		Console.ReadLine()

	End Sub

End Module

関連する記事

ServerXMLHTTP60(Msxml2.ServerXMLHTTP) 用の dll は同梱していますが、SDK より自分で
作成する場合は、以下のリンク先のページ中の「.NET から COM を使う」のリンク先を参照して
下さい

VB.net : COMの Msxml2.ServerXMLHTTP を使用して http 通信を行う


VB.net : COMの Msxml2.ServerXMLHTTP を使用して URL短縮サービス[bit.ly] を使用する( XML と TEXT )
VB.net : COMの Msxml2.ServerXMLHTTP を使用して Google のURL短縮サービスを使用する( JSON )

VB.NET : 通信

VB.net(2010) : COMの Msxml2.ServerXMLHTTP を使用して WEBアプリにバイナリデータを POST する

VB.net : TKFP.DLL 1.4.3 を使って FTPS でファイル(フォルダ)の一覧を取得する

VB.net : COMの Msxml2.ServerXMLHTTP を使用して Google のURL短縮サービスを使用する( JSON )

VB.net : COMの Msxml2.ServerXMLHTTP を使用して URL短縮サービス[bit.ly] を使用する( XML と TEXT )

VB.net : COMの Msxml2.ServerXMLHTTP を使用して WEBアプリにデータを POST する

VB.net : COMの Msxml2.ServerXMLHTTP を使用して http 通信を行う

VB.net : IPアドレスを IPv4 と IPv6 に区別して取得する

Json.NET を使用して JSON 文字列を VB.net で使用する( 逆シリアライズ )

VB.net : クライアントが送ったヘッダを表示するだけの HTTPサーバー�U

VB.net : クライアントが送ったヘッダを表示するだけの HTTPサーバー( TcpListener )

VB.NET : TKMP.DLL でメール送信