VBScript を『管理者として実行する』には、Shell の runas ( 右クリックメニューの実行と同等 ) で実現します / Jscript も追加

VBScript を『管理者として実行する』には、以下の内容ををスクリプトの先頭に記述します

🔻 VBScript

Set obj = Wscript.CreateObject("Shell.Application")
if Wscript.Arguments.Count = 0 then
	obj.ShellExecute "wscript.exe", WScript.ScriptFullName & " runas", "", "runas", 1
	Wscript.Quit
end if

Wscript.Echo "ここは管理者権限で実行されます"

🔻 Jscript
※ Jscript は WScript 等、大文字小文字の区別があるので注意です。

var obj = new ActiveXObject("Shell.Application");
if ( WScript.Arguments.length == 0 ) {
	obj.ShellExecute( "wscript.exe", WScript.ScriptFullName + " runas", "", "runas", 1 );
	WScript.Quit();
}

WScript.Echo( "ここは管理者権限で実行されます" );

Shell.ShellExecute method

これは、VBScript から利用可能な Shell の機能を使って、右クリックメニューにある『管理者として実行』を実行する方法です。ここでは日本語では無く runas と言う文字列を使って管理者として実行させています。

但し、引数がなかった場合の処理としては処理終了します。ですからこのスクリプトでは、引数をダミーで一つセットして( この場合一つめの runas がそうです )自分自身を再度呼び出しています。

つまり、Windows からすれば二度目の実行が管理者としての実行になります。

この場合は、スクリプトに引数を渡す事ができません。もし渡したい場合は、違ったトリックを使う必要があるのに注意して下さい。(その場合は、外部ファイルから入力するのがもっとも簡単で確実だと思います)

VBScript : キーストロークをウインドウに送信して、キー操作をした事にする( 例 : リモート デスクトップ接続ダイアログ )

リモート デスクトップ接続は開いた後、詳細画面が表示されないので、ALT+O を送り、その後 SHIFT+TAB でタブを選択して、右矢印で次のタブに移動させます。

Set WshShell = CreateObject("WScript.Shell")
WshShell.Run( "mstsc.exe" )

WScript.Sleep(500)
WshShell.AppActivate("リモート デスクトップ接続")
WScript.Sleep(500)

' キーストロークを送信
WshShell.SendKeys ("%O")
WScript.Sleep(500)
WshShell.SendKeys ("+{TAB}")
WScript.Sleep(500)
WshShell.SendKeys ("{RIGHT}")

※ キーストロークの送信は環境や状況によっては、うまく動作しないかもしれません。その場合は適宜変更して下さい(キーストローク詳細)

エクスプローラのフォルダから管理者権限でコマンドプロンプトを開く / 右クリックから『送る』で開く

Set obj = CreateObject("Shell.Application")
Set WshShell = CreateObject( "WScript.Shell" )
obj.ShellExecute "cmd.exe", "/s /k pushd """ & WScript.Arguments(0) & """", "", "runas", 1

保存時のエクスプローラをのアドレスで sendto と入力して保存して下さい。(『送る』フォルダに保存されます )
その後、エクスプローラのフォルダを選択して右クリックで『送る』から 管理者コマンド.vbs を選択します
( 拡張子を表示しない設定では、管理者コマンド と表示されます )

管理者権限でコマンドプロンプトを開く VBScript をエクスプローラの右クリックで開く( そのフォルダで開く )方法

第一引数にフォルダのパスを指定するようにしています。指定しなければ、カレントフォルダで開きます。

管理者で実行するのは、ShellExecute に、"runas" を渡して実行しているからです。これは、右クリックで表示されるメニューにある『管理者として実行』に相当します
acmd.vbs

Set obj = CreateObject("Shell.Application")
Set WshShell = CreateObject( "WScript.Shell" )
if WScript.Arguments.Count <> 0 then
	obj.ShellExecute "cmd.exe", "/s /k pushd """ & WScript.Arguments(0) & """", "", "runas", 1
else
	obj.ShellExecute "cmd.exe", "/s /k pushd """ & WshShell.CurrentDirectory & """", "", "runas", 1
end if

このスクリプトを Windows の system32 フォルダへコピーして、以下のようにレジストリ登録すると、フォルダを右クリックしてその場所で実行可能になります
( Windows の system32 フォルダである必要はありません / PC 共通の表現だとこれが間違いないので使用しています  )

※ 32ビットアプリより system32 にアクセスしようとすると、SysWoW64 にリダイレクトされます

Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\Folder\shell\acmd]
@="管理者コマンドプロンプト"

[HKEY_CLASSES_ROOT\Folder\shell\acmd\command]
@="wscript c:\\windows\\system32\\acmd.vbs \"%V\""

※ system32 フォルダへコピーしたスクリプトを編集するには、エディタの実行時に『管理者として実行』する必要があります。

単に管理者としてコマンドプロンプトを開きたい場合は、Windowsキー + S で『ここに入力して検索』内に cmd と入力して CTRL + SHIFT + ENTER すればいいでしょう

あるいは、通常のコマンドプロンプトを起動して、タスクバーのアイコンを Ctrl と Shift キーを押しながらクリックします。



関連する外部の記事

windows - How to run vbs as administrator from vbs? - Stack Overflow

シャットダウンダイアログを表示する / ログオフ・リブート・シャットダウン / VBScript

※ Windows10 でも動作確認しました

Set objShell = CreateObject("Shell.Application")
objShell.ShutdownWindows()

▼ 右クリックから保存して下さい。
ブラウザでダウンロード
※ クリックすると、新しいウインドウで『プレーンテキスト(text/plain)』として開きます
ログオフ
シャットダウン
リブート
パワーオフ(こちらの環境では未確認)

logoff.vbs

Set colOperatingSystems = _
GetObject("winmgmts:{(Shutdown)}").ExecQuery( _
"Select * from Win32_OperatingSystem") 
For Each objOperatingSystem in colOperatingSystems 
	ObjOperatingSystem.Win32Shutdown(0) 
Next

関連するスクリプト

ログオフ・リブート・シャットダウン

Windows のファイルの『更新日付』のみ VBScript + Shell.Application で変更

更新日付のみです。作成日とアクセス日付は変更できません。

FolderItem.ModifyDate property

Dim objShell

Set objShell = CreateObject("Shell.Application")

Set objFolder = objShell.NameSpace("C:\Users\lightbox\Documents")
if (not objFolder is nothing) then

	Dim objFolderItem
				
	Set objFolderItem = objFolder.ParseName("test.zip")
	if (not objFolderItem is nothing) then
		objFolderItem.ModifyDate = "01/01/2010 0:00:00 AM"
	end if
end if